[AS3]as3数组元素如何实现分页功能代码示例(2)

 实现分页的类

package pages  
{  
          
 
        public class PageManager  
        {  
                private var items:Array;  
 
                //当前索引  
                private var _index:int=0;  
 
                public function PageManager()  
                {  
                        this.items=new Array;  
                        _index=0;  
                }  
 
                /**  
                 *当前页索引  
                 * @return  
                 *  
                 */  
                public function get index():int  
                {  
                        return current.index;  
                }  
 
                /**  
                 *对数组执行分页  
                 * @param items  
                 * @param pagePerSize 每页大小  
                 * @return  分页后的第一页  
                 *  
                 */  
                public function page(items:Array, pagePerSize:int=6):Page  
                {  
                        var page:Page=null;  
                        if (items != null && items.length > 0 && pagePerSize > 0)  
                        {  
                                if (pagePerSize < items.length)  
                                {  
                                        //最后一页的数目  
                                        var left:int=items.length % pagePerSize;  
                                        var pageCount:int=(items.length - left) / pagePerSize;  
                                        for (var i:int=0; i < pageCount; i++)  
                                        {  
                                                page=new Page();  
                                                //每页的容量  
                                                page.capacity=pagePerSize;  
                                                for (var j:int=0; j < pagePerSize; j++)  
                                                {  
                                                        page.add(items[i * pagePerSize + j]);  
                                                }  
                                                //页索引(从0开始)  
                                                page.index=i;  
                                                this.items.push(page);  
                                        }  
                                        //最后一页  
                                        if (left > 0)  
                                        {  
                                                page=new Page();  
                                                page.capacity=pagePerSize;  
                                                page.index=pageCount;  
                                                for (i=items.length - left; i < items.length; i++)  
                                                {  
                                                        page.add(items[i]);  
                                                }  
                                                this.items.push(page);  
                                        }  
                                        if (this.items.length > 0)  
                                        {  
                                                page=this.items[0] as Page;  
                                        }  
                                }  
                                else  
                                {  
                                        //所有元素当做一页  
                                        page=new Page();  
                                        page.capacity=items.length;  
                                        page.index=0;  
                                        for (var t:int=0; t < items.length; t++)  
                                        {  
                                                page.add(items[t]);  
                                        }  
                                        this.items.push(page);  
                                }  
                        }  
                        return page;  
                }  
 
                public function next():Page  
                {  
                        var page:Page=null;  
                        if (hasNext())  
                        {  
                                _index++;  
                                page=items[_index] as Page;  
                        }  
                        return page;  
                }  
 
                public function previous():Page  
                {  
                        var page:Page=null;  
                        if (hasPrevious())  
                        {  
                                _index--;  
                                page=items[_index] as Page;  
                        }  
                        return page;  
                }  
 
                public function hasNext():Boolean  
                {  
 
                        var idx:int=_index;  
                        return (idx + 1) in items;  
 
                }  
 
                public function hasPrevious():Boolean  
                {  
                        var idx:int=_index;  
                        return (idx - 1) in items;  
                }  
 
                /**  
                 * 页数  
                 * @return  
                 *  
                 */  
                public function get count():int  
                {  
                        return items.length;  
                }  
 
                /**  
                 *获取指定页  
                 * @param index  
                 * @return  
                 *  
                 */  
                public function getPageAt(index:int):Page  
                {  
                        var obj:Page=null;  
                        if (index in items)  
                        {  
                                obj=items[index] as Page;  
                        }  
                        return obj;  
                }  
 
                /**  
                 *当前页  
                 * @return  
                 *  
                 */  
                public function get current():Page  
                {  
                        var page:Page=null;  
                        if (_index in items)  
                        {  
                                page=items[_index] as Page;  
                        }  
                        return page;  
                }  
 
                /**  
                 *字符串描述  
                 * @return  
                 *  
                 */  
                public function toString():String  
                {  
                        return items.toString();  
                }  
        }  
}