[AS3]as3.0的Sound类学习案例代码

[AS3]Sound类学习案例

/*=================Sound类学习案例===============  
涉及Sound类 textFile类  textArea类 数组  
案例思路：首先创建一个数组用于存放歌曲列表  
随机选取一首歌并载入  
当载入完毕马上开始播放  
在界面中显示歌曲文件名，并用for in在文本域中显示id3信息  
经验心得：无法直接用代码创建TextArea，前提是库中有TextArea组件  
System.useCodePage=true;只能用于解决载入外部文本时出现的中文乱码  
无法彻底解决中文乱码  
=================Sound类学习案例===============*/  
 
package {  
    import flash.events.Event;  
    import flash.media.Sound;  
    import flash.events.ProgressEvent;  
    import flash.events.IOErrorEvent;  
    import flash.net.URLRequest;  
    import flash.display.Sprite;  
    import flash.text.TextField;  
    import fl.controls.TextArea;  
    import flash.system.System;  
 
 
    public class mySound extends Sprite {  
        /*====================构造函数==================*/  
        public function mySound() {  
 
            var songArray:Array=new Array();  
            songArray=["爱你是我的呼吸.mp3","黄玫瑰.mp3","离别也是爱.mp3"];//创建数组 定义歌曲路径列表  
 
            var songNum:uint=songArray.length*Math.random();  
            var songPath:URLRequest=new URLRequest(songArray[songNum]);//随机播放歌曲的路径  
 
            var songInfo:TextField=new TextField();  
            songInfo.x=50;  
            songInfo.y=40;  
            songInfo.htmlText="<u>歌曲：</u>"+songArray[songNum];//创建一个文本框 用来存放歌曲的文件名 坐标为（50，40）  
            addChild(songInfo);  
 
            var songID3Info:TextArea=new TextArea();  
            songID3Info.setSize(100,50);  
            songID3Info.x=50;  
            songID3Info.y=60;  
            songID3Info.alpha=0.2;  
            addChild(songID3Info);//创建一个文本域，用以存放id3信息  
 
            System.useCodePage=true;//本以为能指望解决中文乱码的问题，可是无效！！！！  
 
            var mySong:Sound=new Sound();  
            mySong.load(songPath);//创建歌曲 并载入歌曲  
 
            mySong.addEventListener(Event.COMPLETE,onLoaded);  
            mySong.addEventListener(ProgressEvent.PROGRESS,loadProgress);  
            mySong.addEventListener(IOErrorEvent.IO_ERROR,onIOError);  
            mySong.addEventListener(Event.ID3, id3Handler);  
 
            /*====================播放函数==================*/  
            function onLoaded(event:Event):void {  
                var localSong:Sound=event.target as Sound;  
                localSong.play();  
            }  
 
            /*====================载入函数==================*/  
            function loadProgress(event:ProgressEvent):void {  
                var percent:uint=Math.round(100*event.bytesLoaded/event.bytesTotal);  
                trace("载入"+percent+"%");  
            }  
            /*===================容错函数===================*/  
            function onIOError(event:IOErrorEvent) {  
                trace("该声音没有被载入: " + event.text);  
            }  
 
            /*=================获取mp3的ID3数据===============*/  
            function id3Handler(event:Event):void {  
                trace("音乐的ID3信息如下:");  
                for (var s in mySong.id3) {  
                    songID3Info.appendText("\n");  
                    songID3Info.appendText(s);  
                    songID3Info.appendText(":");  
                    songID3Info.appendText( mySong.id3[s]);  
                }  
            }  
        }  
    }  
}