[AS3]as3.0侦测摄像头当前状态的源代码

Camera 类包含多个属性，这些属性允许您监视 Camera 对象的当前状态。例如，以下代码使用一个 Timer 对象和一个文本字段实例在显示列表上显示摄像头的若干属性：

var vid:Video;  
var cam:Camera = Camera.getCamera();  
var tf:TextField = new TextField();  
tf.x = 300;  
tf.autoSize = TextFieldAutoSize.LEFT;  
addChild(tf);  
//cuplayer.com侦测摄像头的状态 
if (cam != null)  
{  
    cam.addEventListener(StatusEvent.STATUS, statusHandler);  
    vid = new Video();  
    vid.attachCamera(cam);  
}  
function statusHandler(event:StatusEvent):void  
{  
    if (!cam.muted)  
    {  
        vid.width = cam.width;  
        vid.height = cam.height;  
        addChild(vid);  
        t.start();  
    }  
    cam.removeEventListener(StatusEvent.STATUS, statusHandler);  
}  
  
var t:Timer = new Timer(100);  
t.addEventListener(TimerEvent.TIMER, timerHandler);  
function timerHandler(event:TimerEvent):void  
{  
    tf.text = "";  
    tf.appendText("activityLevel: " + cam.activityLevel + "\n");  
    tf.appendText("bandwidth: " + cam.bandwidth + "\n");  
    tf.appendText("currentFPS: " + cam.currentFPS + "\n");  
    tf.appendText("fps: " + cam.fps + "\n");  
    tf.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");  
    tf.appendText("loopback: " + cam.loopback + "\n");  
    tf.appendText("motionLevel: " + cam.motionLevel + "\n");  
    tf.appendText("motionTimeout: " + cam.motionTimeout + "\n");  
    tf.appendText("quality: " + cam.quality + "\n");  
} 

每 1/10 秒（100 毫秒），即会调度一次 Timer 对象的 timer 事件，并且 timerHandler() 函数会更新显示列表上的文本字段。